<?xml version='1.0' encoding='UTF-8'?>
<s:Application    xmlns:d="http://ns.adobe.com/fxg/2008/dt" creationComplete="application1_creationCompleteHandler(event)" xmlns:fx="http://ns.adobe.com/mxml/2009" xmlns:s="library://ns.adobe.com/flex/spark" width="480" height="800" backgroundColor="#FFFFFF" preloaderChromeColor="#FFFFFF" xmlns:components="components.*" xmlns:local="*" >
	<fx:Style source="Main.css"/>
 
	<fx:Script>
		<![CDATA[
			import com.adobe.audio.format.WAVWriter;
 
			import flash.events.SampleDataEvent;
			import flash.media.Microphone;
			import flash.media.Sound;
			import flash.sensors.Accelerometer;
			import flash.utils.ByteArray;
 
			import fr.kikko.lab.ShineMP3Encoder;
 
			import mx.events.FlexEvent;
 
			//variables to move Mary Poppins with the accelerometer
			private var accX:Number = 0;
			private var myAcc:Accelerometer = new Accelerometer();
			private var vAcceleration:Number = 0.5;
			private var vVelocity:Number = -10;
 
			//variables to play with the microphone
			private  var microphone:Microphone;
			private var soundRecording:ByteArray;
			private var soundOutput:Sound;
			private var mp3encoder:ShineMP3Encoder;
 
			private function startMicRecording():void
			{
				soundRecording = new ByteArray();
				microphone.addEventListener(SampleDataEvent.SAMPLE_DATA, gotMicData);
				//UI
				btnRecord.enabled = false;
				btnStop.enabled = true;
				btnPlayback.enabled = false;
				myTI.text = "Press stop";
			}
 
			private function stopMicRecording():void
			{
				microphone.removeEventListener(SampleDataEvent.SAMPLE_DATA, gotMicData);
				//UI
				soundRecording.position = 0;
				btnRecord.enabled = true;
				btnStop.enabled = false;
				btnPlayback.enabled = true;
				convert2MP3();
				myAiguille.rotation = -40;
			}
 
			private function gotMicData(micData:SampleDataEvent):void
			{
				//This is currently recording my voice
				soundRecording.writeBytes(micData.data);
			}
 
			private function getMicActivity(micData:SampleDataEvent):void{
				//To update the Vu-meter indicator
				myAiguille.rotation = 8/10 * microphone.activityLevel - 40;
			}
 
			private function playbackData():void
			{
				//Playback the raw sound data stored in memory
				soundRecording.position = 0;
				soundOutput = new Sound();
				soundOutput.addEventListener(SampleDataEvent.SAMPLE_DATA, playSound);
				soundOutput.play();
			}
 
			private function playSound(soundOutput:SampleDataEvent):void
			{
				trace("inPlaySound");
				if (!soundRecording.bytesAvailable > 0)
					return;
				for (var i:int = 0; i < 8192; i++)
				{
					var sample:Number = 0;
					if (soundRecording.bytesAvailable > 0)
						sample = soundRecording.readFloat();
					soundOutput.data.writeFloat(sample);
					soundOutput.data.writeFloat(sample);
				}
			}
 
			private function convert2MP3():void{
				//First you need to create a WAV file using WAVWriter
				//Then I can encode the WAV file into a MP3 file using Shine
				var wavWrite:WAVWriter = new WAVWriter();
				wavWrite.numOfChannels = 1;
				wavWrite.sampleBitRate = 16;
				wavWrite.samplingRate = 44100;
 
				var wav:ByteArray = new ByteArray();
 
				wavWrite.processSamples(wav, soundRecording, 44100,1);
				wav.position = 0;
 
				mp3encoder = new ShineMP3Encoder(wav);
 
				mp3encoder.addEventListener(Event.COMPLETE, onEncoded);
				mp3encoder.addEventListener(ProgressEvent.PROGRESS, onEncodingProgress);
				myTI.text = "Encoding MP3 file...";
				mp3encoder.start();
			}
 
			private function onEncoded(e:Event):void{
				myTI.text = "Mp3 encoded and saved on your SDcard. Press Play.";
				mp3encoder.mp3Data.position = 0;
				var myDate:Date = new Date();
				var theDate:String = myDate.monthUTC.toString()+myDate.dayUTC.toString()+myDate.hoursUTC.toString()+myDate.minutesUTC.toString()+myDate.secondsUTC.toString();
				mp3encoder.saveAs("myVoice"+theDate+".mp3");
			}
 
			private function onEncodingProgress(evt:ProgressEvent):void{
				myTI.text = "Encoding MP3 "+ evt.bytesLoaded.toString() + "/" + evt.bytesTotal.toString();
			}
 
			protected function application1_creationCompleteHandler(event:FlexEvent):void
			{
				//Starts the microphone to update the UI
				microphone = Microphone.getMicrophone(-1);
				microphone.rate = 44;
				mary.addEventListener(Event.ENTER_FRAME, onEnterMary);
				myAcc.addEventListener(AccelerometerEvent.UPDATE, onAccUpdate);
				microphone.addEventListener(SampleDataEvent.SAMPLE_DATA, getMicActivity);
			}
 
			private function onAccUpdate(evt:AccelerometerEvent):void{
				//Mary Poppins moves from left to right with the accelerometer
				accX = evt.accelerationX * (-1);
			}
 
			private function onEnterMary(evt:Event):void{
				//Logic to make Mary fly
 
				mary.y += vVelocity;
				vVelocity += vAcceleration;
 
				if (mary.y > 635) {
					vVelocity = 0;
					mary.y = 635;
				}else{
					// the treshold is 75 (when you blow on a microphone)
					if(microphone.activityLevel > 75){
						vVelocity = -20;
					}
 
					mary.x -= (mary.x - (mary.x + accX * 10))*0.6;
				}
				if (mary.x > 480) mary.x = 0;
				if (mary.x < 0) mary.x = 480;
			}
 
		]]>
	</fx:Script>
	<!--Code generated by Flash Catalyst CS5-->
	<s:BitmapImage smooth="true" source="@Embed('/assets/images/microphoneAndroid/Background.png')" d:userLabel="Background" x="0" y="0"/>
	<s:BitmapImage smooth="true" source="@Embed('/assets/images/microphoneAndroid/Layer 1.png')" d:userLabel="Layer 1" x="0" y="30"/>
	<s:BitmapImage smooth="true" source="@Embed('/assets/images/microphoneAndroid/Layer 10.png')" d:userLabel="Layer 10" x="0" y="191"/>
	<s:Button click="startMicRecording()"  skinClass="components.Layer8Button" x="36" y="86" id="btnRecord"/>
	<s:Button click="playbackData()" skinClass="components.Layer8copyButton2" x="192" y="86" id="btnPlayback" enabled="false"/>
	<s:BitmapImage alpha="0.07" smooth="true" source="@Embed('/assets/images/microphoneAndroid/Layer 6.png')" d:userLabel="Layer 6" x="0" y="30"/>
	<s:BitmapImage blendMode="multiply" smooth="true" source="@Embed('/assets/images/microphoneAndroid/Layer 7_s Drop Shadow.png')" d:userLabel="Layer 7's Drop Shadow" x="-4" y="-4"/>
	<s:BitmapImage smooth="true" source="@Embed('/assets/images/microphoneAndroid/Layer 7.png')" d:userLabel="Layer 7" x="0" y="0"/>
	<s:RichText color="#ffffff" fontFamily="Adobe Clean" fontSize="14" kerning="off" lineHeight="120%" d:userLabel="ADOBE AIR AND THE MICROPHONE" whiteSpaceCollapse="preserve" x="10" y="11">
		<s:content><s:p><s:span>ADOBE AIR AND THE MICROPHONE</s:span></s:p></s:content>
	</s:RichText>
	<s:Button click="stopMicRecording()" skinClass="components.Layer9Button" x="110" y="87" id="btnStop" enabled="false"/>
	<s:BitmapImage smooth="true" source="@Embed('/assets/images/microphoneAndroid/Layer 2.png')" d:userLabel="Layer 2" visible="false" x="266" y="77"/>
	<s:BitmapImage smooth="true" source="@Embed('/assets/images/microphoneAndroid/Layer 12.png')" d:userLabel="Layer 12" x="7" y="218"/>
	<components:Layer11CustomComponent x="179" y="635" id="mary" />
	<s:Label x="10" y="198" text="Label" width="460" color="#EEEEEE" fontFamily="Verdana" fontSize="10" id="myTI"/>
	<local:aiguille id="myAiguille" x="398" y="155" height="90" width="2" rotation="-39"/>
</s:Application>